2003/OCT/27　

;Title	:Freqencu counter for TR with 100Hz display
;	New Fcounter	[FC30]
;date	:2003/10/21	10/24	BY JA1HWO
;MCU	:AT90S2313+10.24MHz
;-----------------------------------------------
.include "C:\AVRTOOLS\APPNOTES\2313def.inc"
.cseg				;code segment
.org	0

.equ	lcd_enb	= 2	;PB2
.equ	lcd_rs	= 3	;PB3
;			PD4=T0 input
;-----------------------------------------------
.def	itpL	= r3		;for TCNT1
.def	itpH	= r4		;
.def	r_0	= r5		;0
.def	r_1	= r6		;1
.def	Btemp	= r7
.def	int_on	= r8
.def	int_off	= r9
.def	t0_set	= r10
.def	Bbit24	= r11		;temp
.def	temp	= r16		;
.def	stemp1	= r17		;for LCD
.def	stemp2	= r18
.def	dt	= r19		;for LCD
.def	w_cnt1	= r20		;for wait
.def	w_cnt2	= r21
.def	BCDr0	= r23		;digit0,1
.def	BCDr1	= r24		;digit2,3
.def	BCDr2	= r25		;digit4,5
.def	BCDr3	= r26		;digit6,7
.def	BinLow	= r27		;
.def	BinMid	= r28
.def	BinHi	= r29
.def	FC1	= r30		;F DATA
.def	FC2	= r31
;**** Vector Address　****
	rjmp	begin		;Reset handle
	reti			;ex Interrupt 0
	reti			;ex Interrupt 1
	reti			;Input Capture1 Interrupt
	reti			;Output Compare1 Interrupt
	rjmp	gate25		;Overflow1
	rjmp	fc_up		;Overflow0
	reti			;UART Receive Complete
	reti			;UART Data Register Empty
	reti			;UART Transmit Complete
	reti			;Analog Comparator
begin:	ldi	temp,LOW(RAMEND)
	out	SPL,temp	;RAM
	ldi	temp,$ff	;B Port all output
	out	DDRB,temp	;
	ldi	temp,0b01100000	;1=output / 0=input
	out	DDRD,temp	;
	ldi	temp,0b00001111	;pull up
	out	PortD,temp
	ldi	temp,1
	mov	r_1,temp	;for count up
	clr	r_0
	out	TCCR1A,r_0
	ldi	temp,3		;T1 1/64
	out	TCCR1B,temp
	ldi	temp,$e7	;$e700=6400
	mov	itpH,temp
	out	TCNT1H,itpH
	clr	itpL
	out	TCNT1L,itpL
	ldi	temp,0		;T0 off
	out	TCCR0,temp
;
	ldi	temp,$82	;bit 7(T1)+2(T0)
	mov	int_on,temp
	ldi	temp,$80	;t0=count UP
	mov	int_off,temp
	out	TIMSK,int_off	;16bit timer on/fcount off
;-----------------------------------------------
	rcall	lcd_initalize	;LCD set & Test
	ldi	dt,'J'
	rcall	lcd_dsp
	ldi	dt,'A'
	rcall	lcd_dsp
	ldi	dt,'1'
	rcall	lcd_dsp
	ldi	dt,'H'
	rcall	lcd_dsp
	ldi	dt,'W'
	rcall	lcd_dsp
	ldi	dt,'O'
	rcall	lcd_dsp
	ldi	temp,100	;WAIT 0.5S
be2:	rcall	wait_5m
	dec	temp
	brne	be2
	sei			;all interrupt on
;-----------------------------------------------
main:
	clr	FC1		;clear Frequncy data
	clr	FC2		;
	out	TCNT0,FC1	;
m_2:	brtc	m_2		;Gate ON?
	ldi	temp,6		;T0 input down check
	out	TCCR0,temp	;T/C on
	out	TIMSK,int_on	;timer Interrupt on
m_3:	brts	m_3		;Gate off?
	nop
	nop
	out	TIMSK,int_off	;counter stop
	ldi	temp,0		;
	out	TCCR0,temp	;T/C0 off
	rcall	lcddata		;DATA to LCD display
	rjmp	main

;-----------------------------------------------
; Timer-0 Interrupt:count UP	
fc_up:	adiw	FC1,1
	reti
;-----------------------------------------------
; Timer-1 Interrupt:GATE
; 	10.24/(64*6400)=40mS(25Hz)
gate25:	out	TCNT1H,itpH
	out	TCNT1L,itpL	;set
	brtc	gate3
	clt
	reti
gate3:	
	set
	reti
;***********************************************
; 24bit  binary to LCD display 6deg **,***.*
; PORTD 0=h then normal frequency counter.
lcddata:
	in	temp,TCNT0	;read from frequency data
	mov	BinLow,temp
	mov	BinMid,FC1
	mov	BinHi,FC2
	sbic	PinD,0		;SW check
	rjmp	lcdda2
;add or subtract hints
;*2- type:HF reciver	(VFO-IF )
	ldi	temp,$0b	;VFO-9.0123=$1600B
	sub	BinLow,temp	;if add
	ldi	temp,$60
	sbc	BinMid,temp	;adc
	ldi	temp,1
	sbc	BinHi,temp	;adc
;-----------------------------------------------
lcdda2:	rcall	BinBCD		;binary to BCD
	ldi	dt,$80		;LCD address claer
	rcall	lcd_commd	;
	mov	dt,BCDr2	;
	swap	dt		;
	andi	dt,$0f		;100.000/
	brne	lcdda3
	ldi	dt,$20
	rjmp	lcdda4
lcdda3:	ori	dt,$30
lcdda4:	rcall	lcd_dsp
	mov	dt,BCDr2	;
	andi	dt,$0f		;10.000/
	ori	dt,$30
	rcall	lcd_dsp		;to LCD
	ldi	dt,','		;','
	rcall	lcd_dsp
	mov	dt,BCDr1	;
	swap	dt		;
	andi	dt,$0f		;1.000/
	ori	dt,$30
	rcall	lcd_dsp
	mov	dt,BCDr1	;
	andi	dt,$0f		;100/
	ori	dt,$30
	rcall	lcd_dsp
lcdmbk:	mov	dt,BCDr0	;
	swap	dt		;10/
	andi	dt,$0f		;
	ori	dt,$30
	rcall	lcd_dsp
	sbic	PinD,1		;PortD 1=L then 1KHz
	rjmp	lcdda5
	ldi	dt,' '
	rcall	lcd_dsp
	rcall	lcd_dsp
	ret
lcdda5:				;100Hz
	ldi	dt,'.'		;'.'
	rcall	lcd_dsp
	mov	dt,BCDr0	;
	andi	dt,$0f		;1/
	ori	dt,$30
	rcall	lcd_dsp
	ret
;-------------------------------------------
.include "fc10blw.inc"
;○BinBCD	:binary to BCD/24bit
;	 BinLow,BinMid,BinHi-BCDr0,BCDr1,BCDr2,BCDr3/Btemp
;○lcd_dsp	:dt=data	:LCD program
;		 stemp1,stemp2(lcd_commd)
;○lcd_commd	:dt=command
;○wait_5m	:10MHz Wait	w_cnt2/w_cnt1